Comment afficher le nom du jour férié à côté d’une date dans Excel ?

Sans l’add-in

Avec la date en A2, saisissez en B2 :

=SIERREUR(
  INDEX(
    {"Jour de l'an";"Fête du travail";"Victoire 1945";"Fête nationale";
     "Assomption";"Toussaint";"Armistice 1918";"Noël"};
    EQUIV(
      TEXTE(A2;"jjmm");
      {"0101";"0105";"0805";"1407";"1508";"0111";"1111";"2512"};
      0
    )
  );
  SIERREUR(
    INDEX(
      {"Lundi de Pâques";"Ascension";"Lundi de Pentecôte"};
      EQUIV(
        A2-PLANCHER(DATE(ANNEE(A2);5;JOUR(MINUTE(ANNEE(A2)/38)/2+56));7)+34;
        {1;39;50};
        0
      )
    );
    ""
  )
)

Les retours à la ligne ne servent qu’à la lecture : le bouton « Copier » copie la formule sur une seule ligne, prête à coller dans une cellule (collée dans la barre de formule, la version sur plusieurs lignes est aussi acceptée par Excel).

La cellule reste vide pour un jour ordinaire. Mêmes limites que pour le repérage des jours fériés : formule longue, à recopier dans chaque classeur.

Avec l’add-in

Calendrier Excel Add-in

=JOUR_FERIE.NOM(A2)

Les jours ordinaires restent vides ; les jours fériés portent leur nom (« Noël », « Ascension »…). Pour construire un libellé du type « 25/12/2026 – Noël » :

=TEXTE(A2; "jj/mm/aaaa") & SI(JOUR_FERIE.NOM(A2) = ""; ""; " – " & JOUR_FERIE.NOM(A2))

Détails : JOUR_FERIE.NOM (nouvel onglet).

Ce que l’add-in change : Le nom du jour s’obtient avec une seule fonction, sans tableau de noms à maintenir. Découvrir Calendrier Excel Add-in

Comment afficher dans une même colonne le jour férié, à défaut les vacances ?

Sans l’add-in

Utilisez trois colonnes : en B2 la formule du nom du jour férié (ci-dessus), en C2 la formule du nom des vacances (voir vacances scolaires de ma zone), puis en D2 :

=SI(B2<>"";B2;C2)

Avec l’add-in

Une seule formule suffit :

=SI(JOUR_FERIE.NOM(A2) <> ""; JOUR_FERIE.NOM(A2); VACANCES.NOM(A2; $E$1))

Sources

• Jours fériés et ponts dans le secteur privé – Service-Public.fr (nouvel onglet) : liste et noms des fêtes légales.
• Calcul de la date de Pâques – Wikipédia (nouvel onglet) : principe du calcul de la date de Pâques.